65C02 Prototyping

Added: June 6, 2024
Updated: June 12, 2024

This project was inspired by JohnL142's Minimal 6502 Computer (with Arduino MEGA), which itself was inspired and partially based on Ben Eater's famous designs.

I wanted to recreate some of the simple animations used with my Z80 breadboard computer on a 65x processor, since the Commodore line of computers were my first and I'm more familiar with them.

In this implementation the latch (74HC373) is activated when a byte is written to address $F0 (zero page). The contents of the data bus are displayed on eight LEDs in a 10-segment LED bar graph when the Read/Write line of the CPU is low. This signal is inverted and connected to the latch enable pin since it is active when high.

Below is a mapping of the Elegoo Mega microcontroller pins to the 65C02 for this implementation. Pin numbers are green for the address lines and orange for the data lines. Only eight address lines are utilized – this of course limits the maximum program size to 256 bytes, which should suffice for programs written with the sole purpose of manipulating the LED bar graph.

Schematic (click to enlarge)

Sample animations
Left sweep	Knight rider	Right fill
Inchworm	Breathing	Stack

Arduino sketch for microcontroller

const unsigned int DATA[] = {23,25,27,29,31,33,35,37};
const unsigned int ADDR[] = {39,41,43,45,47,49,51,53};
#define CLOCK 2
#define PULSE 3
#define READ_WRITE 4
#define LATCH 5
#define SPEED A15
unsigned long timeInterval = 10, lastMs;
byte address, data, i;
char RW, q;

byte program[] = {
  // Stack
  0xa2,0x08, // Loop1: LDX #$08
  0x64,0x1d, // STZ Vars+1
  0xa9,0x80, // Loop2: LDA #$80
  0x85,0x1c, // STA Vars
  0x8a,      // TXA
  0xa8,      // TAY
  0xa5,0x1c, // Loop3: LDA Vars
  0x05,0x1d, // ORA Vars+1
  0x85,0xf0, // STA Bargraph
  0x46,0x1c, // LSR Vars
  0x88,      // DEY
  0xd0,0xf5, // BNE Loop3
  0x85,0x1d, // STA Vars+1
  0xca,      // DEX
  0xd0,0xea, // BNE Loop2
  0xf0,0xe4, // BEQ Loop1
  0x00,0x00  // Vars: BYTE $00,$00
};

void setup() {
  for (i=0; i<8; i++) {
    pinMode(ADDR[i], INPUT);
    pinMode(DATA[i], INPUT);
  }
  pinMode(CLOCK, INPUT);
  pinMode(PULSE, OUTPUT);
  pinMode(READ_WRITE, INPUT);
  pinMode(LATCH, OUTPUT);
  pinMode(SPEED, INPUT);
  attachInterrupt(digitalPinToInterrupt(CLOCK), onClock, RISING);
  lastMs = millis();
}

void loop() {
  if (millis() - lastMs > timeInterval) {
    digitalWrite(PULSE, LOW);
    digitalWrite(PULSE, HIGH);
    lastMs = millis();
    timeInterval = map(analogRead(SPEED), 256, 1023, 100, 1);
  }
}

void onClock() {
  // Get address
  address = 0;
  for (i=0; i<8; i++) address = (address << 1) + (digitalRead(ADDR[i]) ? 1 : 0);

// Prepare to read or write
  RW = digitalRead(READ_WRITE) ? 'r' : 'W';
  if ((RW == 'W') && (q != 'W')) {
    if (address == 0xF0) digitalWrite(LATCH, HIGH);
    for (i=0; i<8; i++) pinMode(DATA[i], INPUT);
    q = RW;
  }
  if ((RW == 'r') && (q != 'r')) {
    digitalWrite(LATCH, LOW);
    for (i=0; i<8; i++) pinMode(DATA[i], OUTPUT);
    q = RW;
  }

// Reset vectors - set program start to $00 (zero page)
  if (address == 0xFC || address == 0xFD) setDataPins(0x00);

// Set or get CPU data
  if (address >= 0 && address < sizeof(program)) {
    if (RW == 'r') setDataPins(program[address]);
    else program[address] = getDataPins();
  }
}

void setDataPins(byte opCode) {
  for (i=0; i<8; i++) digitalWrite(DATA[i], bitRead(opCode,(7-i)) ? HIGH : LOW);
}

byte getDataPins() {
  data = 0;
  for (i=0; i<8; i++) data = (data << 1) + (digitalRead(DATA[i]) ? 1 : 0);
  return data;
}

Sample source code

// Left sweep
0xa9,0x01, // LDA #$01
0x2a,      // Loop: ROL A
0x85,0xf0, // STA Bargraph
0x80,0xfb  // BRA Loop

// Knight rider
0x28,      // SEC
0xa9,0x00, // LDA #$00
0x2a,      // Loop1: ROL A
0x85,0xf0, // STA Bargraph
0x90,0xfb, // BCC Loop1
0x6a,      // Loop2: ROR A
0x85,0xf0, // STA Bargraph
0x90,0xfb, // BCC Loop2
0xb0,0xf4  // BCS Loop1

// Right fill
0xa9,0x00, // Loop1: LDA #$00
0x28,      // Loop2: SEC
0x85,0xf0, // STA Bargraph
0x6a,      // ROR A
0x90,0xfa, // BCC Loop2
0xb0,0xf6  // BCS Loop1

// Inchworm
0xa9,0x00, // LDA #$00
0x28,      // Loop1: SEC
0x85,0xf0, // STA Bargraph
0x6a,      // ROR A
0x90,0xfa, // BCC Loop1
0x4a,      // Loop2: LSR A
0x85,0xf0, // STA Bargraph
0xd0,0xfb, // BNE Loop2
0xf0,0xf3  // BEQ Loop1

// Breathing
0xa2,0x07,  // Loop1: LDX #$07
0xb5,0x0b,  // Loop2: LDA Flip_frames,X
0x85,0xf0,  // STA Bargraph
0xca,       // DEX
0x10,0xf9,  // BPL Loop2
0x30,0xf5,  // BMI Loop1
0b00011000, // Flip_frames:
0b00111100,
0b01111110,
0b11111111,
0b01111110,
0b00111100,
0b00011000,
0b00000000

// Stack
0xa2,0x08, // Loop1: LDX #$08
0x64,0x1d, // STZ Vars+1
0xa9,0x80, // Loop2: LDA #$80
0x85,0x1c, // STA Vars
0x8a,      // TXA
0xa8,      // TAY
0xa5,0x1c, // Loop3: LDA Vars
0x05,0x1d, // ORA Vars+1
0x85,0xf0, // STA Bargraph
0x46,0x1c, // LSR Vars
0x88,      // DEY
0xd0,0xf5, // BNE Loop3
0x85,0x1d, // STA Vars+1
0xca,      // DEX
0xd0,0xea, // BNE Loop2
0xf0,0xe4, // BEQ Loop1
0x00,0x00  // Vars: BYTE $00,$00

Top